home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / system / whatuhav.zip / W.BAS < prev    next >
BASIC Source File  |  1987-08-10  |  4KB  |  65 lines
  1. 1 '  What does your IBM PC or compatible have?
  2. 2 '  Find out with this program.  Just type
  3. 3 '  BASICA WHATUHAV and let it tell you.
  4. 4 '  (c) 1985  Thomas Tuerke,       Educational
  5. 5 '            441 San Carlos Way   Software
  6. 6 '            Novato, Ca, 94947    Products
  7. 7 '   License granted to copy and use, but not
  8. 8 '   sell.  REMs and comments must remain.
  9. 9 '
  10. 10 N$=" no":S$="s":DEFINT A-Z:DEF SEG=&H40:KEY OFF
  11. 20 MEMORY  =PEEK(&H13)+PEEK(&H14)*256
  12. 30 DISKS   =(PEEK(&H10) AND &HC0)\&H40+1
  13. 40 HARD    =PEEK(&H75)
  14. 50 PRINTERS=(PEEK(&H11)AND &HC0)\&H40
  15. 60 SERIAL  =(PEEK(&H11)AND &HE)\2
  16. 70 GAMEPORT=(PEEK(&H11)AND &H10)\&H10
  17. 75 IF(PEEK(&H10)AND &H30)=&H30 THEN MONO=-1
  18. 80 DEF FNNUM$(X)=MID$(N$+STR$(X),-3*(X<>0)+1,4)
  19. 100 CLS:COLOR 7,0:GOSUB 900:IF PRINTERS THEN LOCATE 7:GOSUB 920:IF PRINTERS>1 THEN GOSUB 920
  20. 105 IF SERIAL THEN LOCATE 3:GOSUB 930:
  21. 106 IF GAMEPORT THEN LOCATE 1:GOSUB 935:
  22. 110 COLOR 15,0:LOCATE 1,1:PRINT "You have:":EMPTY=2:LOCATE 8,27:PRINT USING"#####K RAM memory";MEMORY:LOCATE 9,43:PRINT "│":LOCATE 10,43:PRINT"│":LOCATE 11,43:PRINT CHR$(25)
  23. 120 LOCATE 13,58:PRINT"7":LOCATE 14,45:PRINT FNNUM$(DISKS)" floppy drive";:IF DISKS<>1 THEN PRINT S$:IF DISKS>1 AND HARD=0 THEN LOCATE 11,65:COLOR 7,0:PRINT "══█══":COLOR 15,0
  24. 130 IF HARD THEN LOCATE 11,65:COLOR 7,0:PRINT CHR$(22):COLOR 15,0:LOCATE 13,68:PRINT "7":LOCATE 14,64:PRINT FNNUM$(HARD)" hard disk";:IF HARD>1 THEN PRINT"s";ELSE ELSE LOCATE EMPTY:EMPTY=EMPTY+1:PRINT "  no hard disk"
  25. 140 IF PRINTERS THEN LOCATE 14,10:PRINT FNNUM$(PRINTERS)" printer port";:IF PRINTERS>1 THEN PRINT"s" ELSE ELSE LOCATE EMPTY:EMPTY=EMPTY+1:PRINT"  no printer ports";:IF SERIAL THEN PRINT " -- do you have":PRINT"    a `serial' printer?":EMPTY=EMPTY+1
  26. 150 IF SERIAL THEN LOCATE 2,28:PRINT FNNUM$(SERIAL)" serial port";:IF SERIAL>1 THEN PRINT"s";ELSE ELSE LOCATE EMPTY,1:EMPTY=EMPTY+1:PRINT "  no serial port
  27. 160 IF GAMEPORT THEN LOCATE 5,77:PRINT "7":LOCATE 6,75:PRINT "game":LOCATE 7,75:PRINT"port" ELSE LOCATE EMPTY,1:EMPTY=EMPTY+1:PRINT "  no game port"
  28. 170 LOCATE 4,47:IF MONO THEN PRINT "Monochrome" ELSE PRINT "Color/Graphics"
  29. 171 LOCATE 5,47:PRINT"Screen adaptor"
  30. 899 COLOR 7,0:LOCATE 22,1:SYSTEM
  31. 900 LOCATE 1,40:PRINT "    ╔════════════════════════╗
  32. 901 LOCATE,40:PRINT "    ║ ┌───────────────┐      ║
  33. 902 LOCATE,40:PRINT "    ║ │               │      ║
  34. 903 LOCATE,40:PRINT "    ║ │               │      ║
  35. 904 LOCATE,40:PRINT "    ║ │               │  o   ║
  36. 905 LOCATE,40:PRINT "    ║ │               │  o   ║
  37. 906 LOCATE,40:PRINT "    ║ └───────────────┘      ║
  38. 907 LOCATE,40:PRINT "    ╚══╤╤════════════════╤╤══╝
  39. 908 LOCATE,40:PRINT "╔══════╧╧════════════════╧╧══════╗
  40. 909 LOCATE,40:PRINT "║ ▄          ┌─────────────────┐ ║
  41. 910 LOCATE,40:PRINT "║            │ ══█══  │        │ ║
  42. 911 LOCATE,40:PRINT "║ ║║║║║║║║║  └─────────────────┘ ║
  43. 912 LOCATE,40:PRINT "╚════════════════════════════════╝
  44. 913 LOCATE,40:PRINT "  ≡":LOCATE,40:PRINT"  ≡
  45. 914 LOCATE,40:PRINT "┌────────────────────────────────┐
  46. 915 LOCATE,40:PRINT "│════════════════════════════════│
  47. 916 LOCATE,40:PRINT "│"+STRING$(2,22)+" "+STRING$(29,22)+"│
  48. 917 LOCATE,40:PRINT "│"+STRING$(2,22)+" ▄"+STRING$(22,22)+"█"+STRING$(4,22)+"█│
  49. 918 LOCATE,40:PRINT "│"+STRING$(2,22)+" ▄"+STRING$(4,22)+STRING$(14,220)+STRING$(9,22)+"█│
  50. 919 LOCATE,40:PRINT "└────────────────────────────────┘":RETURN
  51. 920 PRINT "      ┌┐";:COLOR 0,7:PRINT"∙              ∙";:COLOR 7,0:PRINT"┌┐
  52. 921 PRINT "      ││";:COLOR 0,7:PRINT"∙              ∙";:COLOR 7,0:PRINT"││
  53. 922 PRINT "      ││";:COLOR 0,7:PRINT"∙              ∙";:COLOR 7,0:PRINT"││
  54. 923 PRINT "╔═════╧╧════════════════╧╧═════╗
  55. 924 PRINT "║ ▀▀                     ■■■   ║
  56. 925 PRINT "║──────────────────────────────║
  57. 926 PRINT "╚══════════════════════════════╝":PRINT:RETURN
  58. 930 LOCATE,28:PRINT "┌───═══════───┐
  59. 931 LOCATE,28:PRINT "└──▄───────▄──┘":RETURN
  60. 935 LOCATE,74:PRINT"  ▄
  61. 936 LOCATE,74:PRINT"  ║
  62. 938 LOCATE,74:PRINT"┌─╨─┐
  63. 939 LOCATE,74:PRINT"└───┘":RETURN
  64.  
  65.